DE150-501N04A View Datasheet(PDF) - IXYS CORPORATION
Part Name
Description
Manufacturer
DE150-501N04A Datasheet PDF : 5 Pages
| |||
DE150-501N04A
RF Power MOSFET
501N04A DE-SERIES SPICE Model
The DE-SERIES SPICE Model is illustrated in Figure 6. The model is an expansion of
the SPICE level 3 MOSFET model. It includes the stray inductive terms LG, LS and LD.
Rd is the RDS(ON) of the device, Rds is the resistive leakage term. The output capaci-
tance, COSS, and reverse transfer capacitance, CRSS are modeled with reversed biased
diodes. This provides a varactor type response necessary for a high power device
model. The turn on delay and the turn off delay are adjusted via Ron and Roff.
Figure 6 DE-SERIES SPICE Model
This SPICE model may be downloaded as a text file from the IXYSRF web site at
http://www.ixysrf.com/products/switch_mode.html
http://www.ixysrf.com/spice/de150-501n04a.html
Net List:
*SYM=POWMOSN
.SUBCKT 501N04A 10 20 30
* TERMINALS: D G S
* 500 Volt 4.5 Amp 1.5 Ohm N-Channel Power MOSFET 10-30-2001
M1 1 2 3 3 DMOS L=1U W=1U
RON 5 6 9.5
DON 6 2 D1
ROF 5 7 3.5
DOF 2 7 D1
D1CRS 2 8 D2
D2CRS 1 8 D2
CGS 2 3 .6N
RD 4 1 1.5
DCOS 3 1 D3
RDS 1 3 5.0MEG
LS 3 30 .1N
LD 10 4 1N
LG 20 5 1N
.MODEL DMOS NMOS (LEVEL=3 VTO=3.0 KP=6.0)
.MODEL D1 D (IS=.5F CJO=1P BV=100 M=.5 VJ=.6 TT=1N)
.MODEL D2 D (IS=.5F CJO=175P BV=500 M=.5 VJ=.6 TT=1N RS=10M)
.MODEL D3 D (IS=.5F CJO=250P BV=500 M=.3 VJ=.4 TT=400N RS=10M)
.ENDS
Doc #9200-0240 Rev 5
© 2009 IXYS RF
An IXYS Company
2401 Research Blvd., Suite 108
Fort Collins, CO USA 80526
970-493-1901 Fax: 970-493-1903
Email: sales@ixyscolorado.com
Web: http://www.ixyscolorado.com
Share Link: 